From 5c3e86f2f738fe2cf765a4408bd7815194904938 Mon Sep 17 00:00:00 2001
From: saundersp <pierre.saundersgb@gmail.com>
Date: Sat, 4 Jan 2025 23:03:03 +0100
Subject: [PATCH] Added dev-libs/libportal-0.9.0
---
dev-libs/libportal/Manifest | 1 +
dev-libs/libportal/libportal-0.9.0.ebuild | 113 ++++++++++++++++++++
metadata/md5-cache/dev-libs/libportal-0.9.0 | 17 +++
3 files changed, 131 insertions(+)
create mode 100644 dev-libs/libportal/libportal-0.9.0.ebuild
create mode 100644 metadata/md5-cache/dev-libs/libportal-0.9.0
diff --git a/dev-libs/libportal/Manifest b/dev-libs/libportal/Manifest
index 5bbe26d..df69870 100644
--- a/dev-libs/libportal/Manifest
+++ b/dev-libs/libportal/Manifest
@@ -1 +1,2 @@
DIST libportal-0.8.1.tar.xz 103136 BLAKE2B 11ae7c64c519320671d89f61d97b1adb0b78089c0ea5fcbaf24078cacd23562569b4a4ae012cbdb9feda168bf6af8ec0dbf663dc2b4fb8d7b68818bb6f68911d SHA512 b0c5d108be63261804dbcb8ef923d023c47017a0bd990b3db669d30257f6adabfe682b704d771397781ea4054a07c0a71d945cddfe41a4983e8f88e99952eb68
+DIST libportal-0.9.0.tar.xz 107488 BLAKE2B 8ec0b10511b0431e8b518b8ffbf3fc5c2d73d4f19c678aacd62042dc9082045eb0d438f4f476f61648673a947bf3054562f6de21c9dff7e6a03d00f96748d97e SHA512 b0c7a7f4b3f50b8bf9d5403b484b81127b6344907b409e87197fbc643111e03ef20532ce2012e285c25dedb8698a214b2decdf9fc48256a82ebe617bb3d05d79
diff --git a/dev-libs/libportal/libportal-0.9.0.ebuild b/dev-libs/libportal/libportal-0.9.0.ebuild
new file mode 100644
index 0000000..06ae8bc
--- /dev/null
+++ b/dev-libs/libportal/libportal-0.9.0.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+inherit flag-o-matic meson python-any-r1 vala virtualx
+
+DESCRIPTION="Flatpak portal library"
+HOMEPAGE="https://github.com/flatpak/libportal"
+SRC_URI="https://github.com/flatpak/libportal/releases/download/${PV}/${P}.tar.xz"
+
+LICENSE="LGPL-3"
+SLOT="0/1-1-1-1" # soname of libportal{,-gtk3,-gtk4,-qt5}.so
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="gtk gtk-doc +introspection qt5 test +vala wayland X"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+ gtk-doc? ( introspection )
+ vala? ( introspection )
+"
+
+RDEPEND="
+ >=dev-libs/glib-2.58:2
+ introspection? ( dev-libs/gobject-introspection:= )
+ gtk? (
+ >=x11-libs/gtk+-3.24.41-r1:3[X?,wayland?]
+ >=gui-libs/gtk-4.12.5-r2:4[X?,wayland?]
+ )
+ qt5? (
+ dev-qt/qtcore:=
+ dev-qt/qtgui:=
+ dev-qt/qtx11extras:=
+ dev-qt/qtwidgets:=
+ )
+"
+DEPEND="${RDEPEND}
+ qt5? (
+ test? ( dev-qt/qttest:= )
+ )
+"
+BDEPEND="
+ dev-util/glib-utils
+ virtual/pkgconfig
+ gtk-doc? ( dev-util/gi-docgen )
+ qt5? (
+ test? ( dev-qt/linguist-tools )
+ )
+ test? (
+ ${PYTHON_DEPS}
+ $(python_gen_any_dep '
+ dev-python/pytest[${PYTHON_USEDEP}]
+ dev-python/dbus-python[${PYTHON_USEDEP}]
+ dev-python/python-dbusmock[${PYTHON_USEDEP}]
+ ')
+ )
+ vala? ( $(vala_depend) )
+"
+
+python_check_deps() {
+ python_has_version \
+ "dev-python/pytest[${PYTHON_USEDEP}]" \
+ "dev-python/dbus-python[${PYTHON_USEDEP}]" \
+ "dev-python/python-dbusmock[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+ if use test; then
+ python-any-r1_pkg_setup
+ fi
+}
+
+src_prepare() {
+ default
+ vala_setup
+}
+
+src_configure() {
+ # defang automagic dependencies
+ use wayland || append-cflags -DGENTOO_GTK_HIDE_WAYLAND
+ use X || append-cflags -DGENTOO_GTK_HIDE_X11
+
+ local emesonargs=(
+ $(meson_feature gtk backend-gtk3)
+ $(meson_feature gtk backend-gtk4)
+ $(meson_feature qt5 backend-qt5)
+ -Dportal-tests=false
+ $(meson_use introspection)
+ $(meson_use vala vapi)
+ $(meson_use gtk-doc docs)
+ $(meson_use test tests)
+ )
+ meson_src_configure
+}
+
+src_test() {
+ # Tests only exist for Qt5
+ if use qt5; then
+ virtx meson_src_test
+ else
+ # run meson_src_test to notice if tests are added
+ meson_src_test
+ fi
+}
+
+src_install() {
+ meson_src_install
+
+ if use gtk-doc; then
+ mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+ mv "${ED}"/usr/share/doc/${PN}-1 "${ED}"/usr/share/gtk-doc/html/ || die
+ fi
+}
diff --git a/metadata/md5-cache/dev-libs/libportal-0.9.0 b/metadata/md5-cache/dev-libs/libportal-0.9.0
new file mode 100644
index 0000000..6ac1665
--- /dev/null
+++ b/metadata/md5-cache/dev-libs/libportal-0.9.0
@@ -0,0 +1,17 @@
+BDEPEND=dev-util/glib-utils virtual/pkgconfig gtk-doc? ( dev-util/gi-docgen ) qt5? ( test? ( dev-qt/linguist-tools ) ) test? ( || ( dev-lang/python:3.13 dev-lang/python:3.12 dev-lang/python:3.11 dev-lang/python:3.10 ) || ( ( dev-lang/python:3.13 dev-python/pytest[python_targets_python3_13(-)] dev-python/dbus-python[python_targets_python3_13(-)] dev-python/python-dbusmock[python_targets_python3_13(-)] ) ( dev-lang/python:3.12 dev-python/pytest[python_targets_python3_12(-)] dev-python/dbus-python[python_targets_python3_12(-)] dev-python/python-dbusmock[python_targets_python3_12(-)] ) ( dev-lang/python:3.11 dev-python/pytest[python_targets_python3_11(-)] dev-python/dbus-python[python_targets_python3_11(-)] dev-python/python-dbusmock[python_targets_python3_11(-)] ) ( dev-lang/python:3.10 dev-python/pytest[python_targets_python3_10(-)] dev-python/dbus-python[python_targets_python3_10(-)] dev-python/python-dbusmock[python_targets_python3_10(-)] ) ) ) vala? ( || ( dev-lang/vala:0.56 ) ) >=dev-build/meson-1.2.3 app-alternatives/ninja dev-build/meson-format-array test? ( x11-base/xorg-server[xvfb] x11-apps/xhost )
+DEFINED_PHASES=compile configure install prepare setup test
+DEPEND=>=dev-libs/glib-2.58:2 introspection? ( dev-libs/gobject-introspection:= ) gtk? ( >=x11-libs/gtk+-3.24.41-r1:3[X?,wayland?] >=gui-libs/gtk-4.12.5-r2:4[X?,wayland?] ) qt5? ( dev-qt/qtcore:= dev-qt/qtgui:= dev-qt/qtx11extras:= dev-qt/qtwidgets:= ) qt5? ( test? ( dev-qt/qttest:= ) )
+DESCRIPTION=Flatpak portal library
+EAPI=8
+HOMEPAGE=https://github.com/flatpak/libportal
+INHERIT=flag-o-matic meson python-any-r1 vala virtualx
+IUSE=gtk gtk-doc +introspection qt5 test +vala wayland X test
+KEYWORDS=~alpha ~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86
+LICENSE=LGPL-3
+RDEPEND=>=dev-libs/glib-2.58:2 introspection? ( dev-libs/gobject-introspection:= ) gtk? ( >=x11-libs/gtk+-3.24.41-r1:3[X?,wayland?] >=gui-libs/gtk-4.12.5-r2:4[X?,wayland?] ) qt5? ( dev-qt/qtcore:= dev-qt/qtgui:= dev-qt/qtx11extras:= dev-qt/qtwidgets:= )
+REQUIRED_USE=gtk-doc? ( introspection ) vala? ( introspection )
+RESTRICT=!test? ( test ) !test? ( test )
+SLOT=0/1-1-1-1
+SRC_URI=https://github.com/flatpak/libportal/releases/download/0.9.0/libportal-0.9.0.tar.xz
+_eclasses_=toolchain-funcs 14648d8795f7779e11e1bc7cf08b7536 multilib b2a329026f2e404e9e371097dda47f96 flag-o-matic f14aba975c94ccaa9f357a27e3b17ffe multiprocessing 1e32df7deee68372153dca65f4a7c21f ninja-utils 2df4e452cea39a9ec8fb543ce059f8d6 python-utils-r1 42c5abe4a656a4993a06a4fc61dbdd12 meson 99466844dd8d4fcfb07578a76f5a9922 python-any-r1 6ddb5e75c10db046f89ebe39c85e1d82 vala e477903dbe0105930c51f170a592dc16 virtualx 9741d451eb64ea8bb9faee90d68a9b68
+_md5_=69449dd28870084d1fea67013b9b622e